VBA voor smarties: Autofilter

Autofilter

1 Van toepassing op

2 Het filterresultaat
2.1 Het filterresultaat markeren
2.2 Het filterresultaat kopiëren
2.3 Het filterresultaat verplaatsen
2.4 Het filterresultaat verwijderen

3 Filtercriteria
3.0 De argumenten van Autofilter

3.1 TEKST

3.2 GETALLEN

3.3 DATUM
3.3.1 Day
3.3.2 Week
3.3.3 Maand
3.3.4 Kwartaal
3.3.5 Jaar
3.3.6 Specifeke maand

3.4 KLEUR

3.5 ICOON
3.5.0 Geen icoon
3.5.1 Iconset 1
3.5.2 Iconset 19
3.5.3 Iconset 9
3.5.4 Iconset 14
3.5.5 Iconset 2
3.5.6 Iconset 10
3.5.7 Iconset 15
3.5.8 Iconset 4
3.5.9 Iconset 6
3.5.10 Iconset 11
3.5.11 Iconset 5
3.5.12 Iconset 13
3.5.13 Iconset 7
3.5.14 Iconset 3
3.5.15 Iconset 8
3.5.16 Iconset 18
3.5.17 Iconset 17
3.5.18 Iconset 20
3.5.19 Iconset 12
3.5.20 Iconset 16

Autofilter is een van de basismethoden in Excel.
In verschillende versies zijn er uitbreidingen geweest die niet alle even uitgebreid gedocumenteerd zijn in VBA.
Deze pagina beschrijft de mogelijkheden in Excel 2010.

1 Van toepassing op

Een autofilter is van toepassing op een kolom: een volledige of een deel van een kolom.
Je kunt kolommen ook als 'velden' van een tabel beschouwen; dan is 'filteren op een kolom' gelijk aan 'filteren op een veld'.

sheet1.columns(3).autofilter 1, ...

De kolom kan deel uitmaken van de usedrange, van een currentregion, een geselecteerd gebied of een tabel (listobject).

sheet1.usedrange.columns(3).autofilter 1, ....
sheet1.usedrange.autofilter 3, ....

sheet1.cells(1).currentregion.columns(3).autofilter 1, ...
sheet1.cells(1).currentregion.autofilter 3, ...

selection.columns(3).autofilter 1, ...
selection.autofilter 3, ...

sheet1.Listobjects(1).range.columns(3).autofilter 1, ...
sheet1.Listobjects(1).range.autofilter 3, ...
sheet1.Listobjects(1).databodyrange.columns(3).autofilter 1, ...
sheet1.Listobjects(1).databodyrange.autofilter 3, ...

Een autofilter is altijd maar op 1 kolom tegelijkertijd aktief.
Wil je op verschillende kolommen filteren dan zul je verschillende autofilters moeten maken.
Die funktioneren dan als "EN" filters: alleen regels die aan beide (of meer) voorwaarden voldoen worden getoond.

2 Het filterresultaat

De eerste rij van een gefilterd gebied beschouwt 'autofilter' als kopregel/veldnamenregel.
Deze eerste rij wordt daarom niet gefilterd en blijft daarom altijd zichtbaar.
Dat heeft gevolgen voor verdere bewerkingen zoals kopiëren, verwijderen, markeren, etc.

Het resultaat van autofilter is, dat rijen die niet aan de filtervoorwaarden voldoen worden verborgen.
Het resultaat bestaat dan ook meestal uit niet aaneengesloten gebieden van zichtbare rijen.

Met de methode .copy kun je de zichtbare gegevens naar een andere plek in het werkblad of werkboek kopiëren.
Daar vormen de gefilterde, gekopieerde gegevens automatisch wél een aaneengesloten gebied.
Dat kan handig zijn om die aaneengesloten gegevens voor validatie of de bevolking van een combobox of listbox te gebruiken.

2.1 Het filterresultaat markeren

Markeer de gefilterde (zichtbare) rijen met een achtergrondkleur.

With cells(1).currentregion

.autofilter 3, "aa17"
.interior.colorindex=3
.autofilter

End With

Omdat de koprij zichtbaar blijft is die nu ook gemarkeerd.
Wil je dat niet, gebruik dan:

With cells(1).currentregion

.autofilter 3, "aa17"
.offset(1).interior.colorindex=3
.autofilter

End With

NB. Nu is door de methode .offset(1) ook de eerste rij onder het gefilterde gebied gemarkeerd.
Wil je dat niet, gebruik dan bijvoorbeeld:

With cells(1).currentregion

.autofilter 3, "aa17"
.offset(1).resize(.rows.count-1).interior.colorindex = 3
.autofilter

End With

2.2 Het filterresultaat kopiëren

Kopieer het gefilterde gebied naar werkblad 'sheet2'.

With cells(1).currentregion

.autofilter 3, "aa17"
.copy sheet2.cells(1)
.autofilter

End With

In tegenstelling tot wat vaak gedacht wordt hoeft geen gebruik gemaakt te worden van specialcells(12) (= alle zichtbare cellen).
De methode copy kopieert automatisch de kopregel/veldnamenregel mee.
Als je dat niet wil:

With cells(1).currentregion

.autofilter 3, "aa17"
.offset(1).copy sheet2.cells(1)
.autofilter

End With

NB. de methode .offset is alleen mogelijk als het resultaat een geldig gebied is. Als je op een volledige kolom zou filteren is .offset(1) bijvoorbeeld niet mogelijk.

2.3 Het filterresultaat verplaatsen: knippen en plakken

De methode Range.Cut kan geen niet-aaneengesloten gebieden verplaatsen.
Die kan daarom niet gebruikt worden in combinatie met autofilter.

2.4 Het filterresultaat verwijderen

De methode Rows.Delete kan wel overweg met een niet-aaneengesloten gebied.

With cells(1).currentregion

.autofilter 3, "aa17"
.entirerow.delete
.autofilter

End With

Houd er rekening mee dat de kopregel/veldnamenrij dan ook wordt verwijderd.
Wil je dat niet gebruik dan:

With cells(1).currentregion

.autofilter 3, "aa17"
.offset(1).entirerow.delete
.autofilter

End With

3 Filtercriteria

Sinds Excel 2007 kan niet alleen gefilterd worden op tekst, getallen of datums, maar ook op kleur (van de celachtergrond of van het lettertype) of op iconen die gebruikt worden bij voorwaardelijke opmaak.
Hieronder voorbeeld VBA-code voor alle verschillende methoden en condities.
In de code wordt uitgegegaan van een tabel (zie het voorbeeldbestand).
In de tweede kolom staat tekst.
In de derde kolom staan datums.
In de vierde kolom staan getallen.

3.0 De argumenten van Autofilter

expression.AutoFilter(Field, Criteria1, Operator, Criteria2, VisibleDropDown)

Field: het nummer van de kolom waarop de filter van toepassing is.
Criteria1: de eerste voorwaarde/criterium voor de filtering.
Operator: een getal of benoemde constante die de toepassing van de filtervoorwaarde(n) modificeert.
Criteria2: een eventule tweede voorwaarde/criterium voor de filtering van dezelfde kolom (hetzelfde veld).
VisibleDropDown: wel/niet tonen van het filtericoon

3.1 TEKST

Tekst is leeg:

Sheet1.ListObjects(1).Range.AutoFilter 2, "="

Tekst is niet leeg:

Sheet1.ListObjects(1).Range.AutoFilter 2, "<>"

Tekst is gelijk aan:

Sheet1.ListObjects(1).Range.AutoFilter 2, "Raisin"
Sheet1.ListObjects(1).Range.AutoFilter 2, "Raisin", 7

Tekst is gelijk aan x of gelijk aan y; operator 2 (xlOr)

Sheet1.ListObjects(1).Range.AutoFilter 2, "Pork", 2, "Quiche"

Tekst is gelijk aan x of gelijk aan y met een Array(); Criteria1 = Array(); operator 7 (xlFilterValues)

Sheet1.ListObjects(1).Range.AutoFilter 2, Array("Pork", "Quiche"), 7

Voor de filtercriteria kun je ook een gebied in het werkblad gebruiken; Criteria1 = Array(); operator 7 (xlFilterValues)

Sheet1.ListObjects(1).Range.AutoFilter 2, [transpose(G1:G2)], 7

Tekst is gelijk aan en gelijk aan; operator 1 (xlAnd)

Sheet1.ListObjects(1).Range.AutoFilter 2, "Pork", 1, "Quiche"

Tekst is niet gelijk aan:

Sheet1.ListObjects(1).Range.AutoFilter 2, "<>Raisin"

Tekst begint met:

Sheet1.ListObjects(1).Range.AutoFilter 2, "Berry*"

Tekst begint niet met:

Sheet1.ListObjects(1).Range.AutoFilter 2, "<>Berry*"

Tekst eindigt met:

Sheet1.ListObjects(1).Range.AutoFilter 2, "*Berry"

Tekst eindigt niet met:

Sheet1.ListObjects(1).Range.AutoFilter 2, "<>*Berry"

Tekst bevat:

Sheet1.ListObjects(1).Range.AutoFilter 2, "*Berry*"
Sheet1.ListObjects(1).Range.AutoFilter 2, "*Be??y*"

Tekst bevat niet:

Sheet1.ListObjects(1).Range.AutoFilter 2, "<>*Berry*"

3.2 GETALLEN

Getal gelijk aan:

Sheet1.ListObjects(1).Range.AutoFilter 4, 146

Getal niet gelijk aan:

Sheet1.ListObjects(1).Range.AutoFilter 4, "<>146"

Getal groter dan:

Sheet1.ListObjects(1).Range.AutoFilter 4, ">146"

Getal groter dan of gelijk aan:

Sheet1.ListObjects(1).Range.AutoFilter 4, ">=146"

Getal kleiner dan:

Sheet1.ListObjects(1).Range.AutoFilter 4, "<146"

Getal kleiner dan of gelijk aan:

Sheet1.ListObjects(1).Range.AutoFilter 4, "<=146"

Getal tussen: operator 1 (xlAnd)

Sheet1.ListObjects(1).Range.AutoFilter 4, "<=146", 1, ">=100"

Getal top 10 hoogste waarden: operator 3 (xltop10items)

Sheet1.ListObjects(1).Range.AutoFilter 4, , 3

Getal top x hoogste:

Je kunt aangeven hoeveel van de hoogste waarden je wil filteren.
Dat aantal geef je aan in het argument Criteria1; de operator voor de filtering vanaf de hoogste waarde blijft onveranderd: 3.
Zo kun je zowel de hoogste 3 waarden als de hoogste 25 waarden filteren met de operator 'xltop10items'.

Getal 12 hoogste waarden: Criteria1 = 12 operator 3 (xltop10items)

Sheet1.ListObjects(1).Range.AutoFilter 4,12 , 3

Getal 10 laagste waarden: operator 4 (xlbottom10items)

Sheet1.ListObjects(1).Range.AutoFilter 4, , 4

Getal x laagste waarden:

Je kunt aangeven hoeveel van de laagste waarden je wil filteren.
Dat aantal geef je aan in het argument Criteria1; de operator voor de filtering vanaf de laagste waarde blijft onveranderd: 4.
Zo kun je zowel de laagste 3 waarden als de laagste 25 waarden filteren met de operator 'xlbottom10items'.

Getal 12 laagste waarden: Criteria1 = 12 operator 4 (xlbottom10items)

Sheet1.ListObjects(1).Range.AutoFilter 4,12 , 4

Getal 10 procent hoogste waarden: operator 5 (xltop10percent)

Sheet1.ListObjects(1).Range.AutoFilter 4, , 5

Getal x procent hoogste waarden:

Je kunt aangeven hoeveel procent van de hoogste waarden je wil filteren.
Dat aantal geef je aan in het argument Criteria1; de operator voor de filtering blijft onveranderd: 5.
Zo kun je zowel de 3 procent hoogste waarden als de 25 procent hoogste waarden filteren met de operator 'xltop10percent'.

Getal 12 procent hoogste waarden: Criteria1 = 12 operator 5 (xltop10percent)

Sheet1.ListObjects(1).Range.AutoFilter 4,12 , 5

Getal 10 procent laagste waarden: operator 6 (xlbottom10percent)

Sheet1.ListObjects(1).Range.AutoFilter 4, , 6

Getal x procent laagste waarden:

Je kunt aangeven hoeveel procent van de laagste waarden je wil filteren.
Dat aantal geef je aan in het argument Criteria1; de operator voor de filtering blijft onveranderd: 6.
Zo kun je zowel de 3 procent laagste waarden als de 25 procent laagste waarden filteren met de operator 'xlbottom10percent'.

Getal 12 procent laagste waarden: Criteria1 = 12 operator 6 (xlbottom10percent)

Sheet1.ListObjects(1).Range.AutoFilter 4,12 , 6

Getal boven het gemiddelde: criterion 33 (xlFilterAboveAverage), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 4, 33, 11

Getal onder het gemiddelde: criterion 34 (xlFilterBelowAverage), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 4, 34, 11

3.3 DATUM

Datum: gelijk aan:

Sheet1.ListObjects(1).Range.AutoFilter 3, "=" & Date - 1

Datum: niet gelijk aan:

Sheet1.ListObjects(1).Range.AutoFilter 3, "<>" & 1 * Date - 1

Datum: (vóór) kleiner dan:

Sheet1.ListObjects(1).Range.AutoFilter 3, "<" & 1 * Date

Datum: (na) groter dan:

Sheet1.ListObjects(1).Range.AutoFilter 3, ">" & 1 * Date

Datum: tussen: operator 1 (xlAnd)

Sheet1.ListObjects(1).Range.AutoFilter 3, ">" & 1 * Date - 30, 1, "<" & 1 * Date + 30

3.3.1 Day

Datum: vandaag: criterion 1 (xlFilterToday), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 1, 11

Datum: gisteren: criterion 2 (xlFilterYesterday), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 2, 11

Datum: morgen: criterion 3 (xlFilterTomorrow), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 3, 11

3.3.2 Week

Datum: deze week: criterion 4 (xlFilterThisWeek), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 4, 11

Datum: vorige week: criterion 5 (xlFilterLastWeek), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 5, 11

Datum: volgende week: criterion 6 (xlFilterNextWeek), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 6, 11

3.3.3 Maand

Datum: deze maand: criterion 7 (xlFilterThisMonth), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 7, 11

Datum: afgelopen maand: criterion 8 (xlFilterLastMonth), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 8, 11

Datum: volgende maand: criterion 9 (xlFilterNextMonth), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 9, 11

3.3.4 Kwartaal

Datum: dit kwartaal: criterion 10 (xlFilterThisQuarter), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 10, 11

Datum: vorig kwartaal: criterion 11 (xlFilterLastQuarter), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 11, 11

Datum: volgend kwartaal: criterion 12 (xlFilterNextQuarter), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 12, 11

3.3.5 Jaar

Datum: dit jaar: criterion 13 (xlFilterThisYear), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 13, 11

Datum: vorig jaar: criterion 14 (xlFilterLastYear), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 14, 11

Datum: volgend jaar: criterion 15 (xlFilterNextYear), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 15, 11

Datum: vanaf vandaag tot 1 jaar geleden: criterion 16 (xlFilterYearToDate), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 16, 11

3.3.6 Specifeke maand

Datum: data in januari: criterion 21 (xlFilterAllDatesInPeriodJanuary), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 21, 11

Datum: data in februari: criterion 22 (xlFilterAllDatesInPeriodFebruray), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 22, 11

Datum: data in maart: criterion 23 (xlFilterAllDatesInPeriodMarch), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 23, 11

Datum: data in april: criterion 24 (xlFilterAllDatesInPeriodApril), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 24, 11

Datum: data in mei: criterion 25 (xlFilterAllDatesInPeriodMay), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 25, 11

Datum: data in juni: criterion 26 (xlFilterAllDatesInPeriodJune), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 26, 11

Datum: data in juli: criterion 27 (xlFilterAllDatesInPeriodJuly), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 27, 11

Datum: data in augustus: criterion 28 (xlFilterAllDatesInPeriodAugust), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 28, 11

Datum: data in september: criterion 29 (xlFilterAllDatesInPeriodSeptember), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 29, 11

Datum: data in oktober: criterion 30 (xlFilterAllDatesInPeriodOctober), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 30, 11

Datum: data in november: criterion 31 (xlFilterAllDatesInPeriodNovember), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 31, 11

Datum: data in december: criterion 32 (xlFilterAllDatesInPeriodDecember), operator 11

Sheet1.ListObjects(1).Range.AutoFilter 3, 32, 11

3.4 KLEUR

Kleur: cel(achtergrond)kleur: operator 8 (xlFilterCellColor)
Voer filterkleur in bij argument Criteria1 als
- getal,
- RGB(12, 23, 56) ,
- &HC6FF00 of
- als eigenschap van een ander object bijv. Cells(1).Interior.Color

Sheet1.ListObjects(1).Range.AutoFilter 4, 8176239, 8
Sheet1.ListObjects(1).Range.AutoFilter 4, rgb(23,46,213), 8
Sheet1.ListObjects(1).Range.AutoFilter 4, &HC6FF00, 8
Sheet1.ListObjects(1).Range.AutoFilter 4, Cells(1).Interior.Color, 8

Kleur: lettertypekleur: operator 9 (xlFilterFontColor)

Sheet1.ListObjects(1).Range.AutoFilter 4, 8176239, 9
Sheet1.ListObjects(1).Range.AutoFilter 4, rgb(23,46,213), 9
Sheet1.ListObjects(1).Range.AutoFilter 4, &HC6FF00, 9
Sheet1.ListObjects(1).Range.AutoFilter 4, Cells(1).Font.Color, 9

Kleur: cel(achtergrond)kleur: geen achtergondkleur of achtergrond via voorwaardelijke opmaak; operator 12 (xlFilterNoFill)

Sheet1.ListObjects(1).Range.AutoFilter 4, , 12

Kleur: lettertypekleur : geen lettertypekleur; operator 13 (xlFilterAutomaticFontColor)

Sheet1.ListObjects(1).Range.AutoFilter 4, , 13

3.5 ICOON

Met voorwaardelijke opmaak kun je iconen gebruiken om de waarden van cellen in een bepaalde gebied te markeren.
Alleen iconen van de 20 ingebouwde iconenverzamelingen kun je daarvoor gebruiken.
Bij autofilter moet je bij 'Criteria1' specificeren op welk icoon uit welke iconenverzameling je wil gaan filteren.

3.5.0 Geen icoon

Criteria1: leeg, operator 14 (xlFilterNoIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, , 14

3.5.1 Iconset 1

Criteria1 = iconsets: 1 (xl3Arrows), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(1).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(1).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(1).Item(3), 10

3.5.2 Iconset 19

Criteria1 = iconsets: 19 (xl3Triangles), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(19).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(19).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(19).Item(3), 10

3.5.3 Iconset 9

Criteria1 = iconsets: 9 (xl4Arrows), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(9).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(9).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(9).Item(3), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(9).Item(4), 10

3.5.4 Iconset 14

Criteria1 = iconsets: 14 (xl5Arrows), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(14).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(14).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(14).Item(3), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(14).Item(4), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(14).Item(5), 10

3.5.5 Iconset 2

Criteria1 = iconsets: 2 ( xl3ArrowsGray), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(2).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(2).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(2).Item(3), 10

3.5.6 Iconset 10

Criteria1 = iconsets: 10 (xl4ArrowsGray), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(10).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(10).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(10).Item(3), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(10).Item(4), 10

3.5.7 Iconset 15

Criteria1 = iconsets: 15 (xl5ArrowsGray), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(15).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(15).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(15).Item(3), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(15).Item(4), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(15).Item(5), 10

3.5.8 Iconset 4

Criteria1 = iconsets: 4 (xl3TrafficLights1), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(4).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(4).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(4).Item(3), 10

3.5.9 Iconset 6

Criteria1 = iconsets: 6 (xl3Signs), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(6).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(6).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(6).Item(3), 10

3.5.10 Iconset 11

Criteria1 = iconsets: 11 (xl4RedToBlack), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(11).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(11).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(11).Item(3), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(11).Item(4), 10

3.5.11 Iconset 5

Criteria1 = iconsets: 5 (xl3TrafficLights2), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(5).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(5).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(5).Item(3), 10

3.5.12 Iconset 13

Criteria1 = iconsets: 13 (xl4TrafficLights), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(13).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(13).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(13).Item(3), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(13).Item(4), 10

3.5.13 Iconset 7

Criteria1 = iconsets: 7 (xl3Symbols), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(7).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(7).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(7).Item(3), 10

3.5.14 Iconset 3

Criteria1 = iconsets: 3 (xl3Flags), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(3).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(3).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(3).Item(3), 10

3.5.15 Iconset 8

Criteria1 = iconsets: 8 (xl3Symbols2), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(8).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(8).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(8).Item(3), 10

3.5.16 Iconset 18

Criteria1 = iconsets: 18 (xl3Stars), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(18).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(18).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(18).Item(3), 10

3.5.17 Iconset 17

Criteria1 = iconsets: 17 (xl5Quarters), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(17).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(17).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(17).Item(3), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(17).Item(4), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(17).Item(5), 10

3.5.18 Iconset 20

Criteria1 = iconsets: 20 (xl5Boxes), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(20).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(20).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(20).Item(3), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(20).Item(4), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(20).Item(5), 10

3.5.19 Iconset 12

Criteria1 = iconsets: 12 (xl4CRV), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(12).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(12).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(12).Item(3), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(12).Item(4), 10

3.5.20 Iconset 16

Criteria1 = iconsets: 16 (xl5CRV), Operator = 10 (xlFilterIcon)

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(16).Item(1), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(16).Item(2), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(16).Item(3), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(16).Item(4), 10

Sheet1.ListObjects(1).Range.AutoFilter 4, ThisWorkbook.Iconsets(16).Item(5), 10